$TITLE  A TRANSPORTATION PROBLEM (TRNSPORT,SEQ=1)
$OFFUPPER
* This problem finds a least cost shipping schedule that meets
* requirements at markets and supplies at factories
*
*  References: 
*              The problem is taken from pg 315 in Magnanti et al text.
*              It is modelled using the framework from the problem in:
*              Dantzig, G B., Linear Programming and Extensions
*              Princeton University Press, Princeton, New Jersey, 1963,
*              Chapter 3-3.
*
*              This formulation is described in detail in Chapter 2 
*              (by Richard E. Rosenthal) of GAMS: A Users' Guide.
*              (A Brooke, D Kendrick and A Meeraus, The Scientific Press,
*              Redwood City, California, 1988.)
*

  SETS
       I   compressor company plants   / CLEVELAND, CHICAGO, BOSTON /
       J   distribution centers   / DALLAS, ATLANTA, SANFRANC, PHILA /;

  PARAMETERS

       A(I)  capacity of plant i in compressor units
         /    CLEVELAND     35
              CHICAGO       50   
              BOSTON        40  /

       B(J)  demand at market j in compressor units
         /    DALLAS    45
              ATLANTA   20
              SANFRANC  30
              PHILA     30   / ;

  TABLE D(I,J)  distribution costs per unit
                     DALLAS        ATLANTA       SANFRANC    PHILA
     CLEVELAND          8             6              10        9
     CHICAGO            9            12              13        7
     BOSTON             14            9              16        5 ;


  PARAMETER C(I,J)  transport cost in dollars per unit ;

            C(I,J) =  D(I,J)  ;

  VARIABLES
       X(I,J)  shipment quantities in units
       Z       total transportation costs in dollars ;

  POSITIVE VARIABLE X ;

  EQUATIONS
       COST        define objective function
       SUPPLY(I)   observe supply limit at plant i
       DEMAND(J)   satisfy demand at market j ;

  COST ..        Z  =E=  SUM((I,J), C(I,J)*X(I,J)) ;

  SUPPLY(I) ..   SUM(J, X(I,J))  =L=  A(I) ;

  DEMAND(J) ..   SUM(I, X(I,J))  =G=  B(J) ;

  MODEL TRANSPORT /ALL/ ;

  SOLVE TRANSPORT USING LP MINIMIZING Z ;

  DISPLAY X.L, X.M ;